Logic Analyzer(?) の製作

[Oct.01 2006] まえがき

Logic Analyzer(?) をある程度動くところまで作ったのでまとめます。もともと PCE 互換機の開発メモに書いていたんですが、あっちのページが直接関係ないものでごちゃごちゃしてきたのでこっちに移動しました。

PCE 互換機の開発メモ　 トップページ

[Jul.23 2006] Logic Analyzer(?) の製作

DRAM (72-pin SIMM) と USB (USBN9604+PIC16F873) と CPLD (XC95108PC84 x 2) を使ってロジックアナライザみたいなものを作ろうとしています。バイナリ値を取り込むだけで、あまりぜいたくな "analyze" 機能を付けるつもりはないので "(?)" 付きです。時間節約のため、メモ風に書いていきます。

↑やっと USB でハードウェアの認識ができた

製作動機

CPU を作るのにステートマシンをなるべくきちんとつくりたい→練習が必要
PCE 互換機のワーク RAM と SCD のバッファ RAM をあわせると結構大容量になる
→ DRAM を使いたい
→ DRAM ってどうやって使うんだっけ？
USB 通信ができれば PC ←→ PCE 互換機の通信がかなり楽になる（RS-232C だとやや能力不足）
ロジックアナライザみたいなものを作っておけば、今後のハードの製作がかなり楽になるはず

所見

どれも重要で、特に製作動機 2 が解決できればかなりいい感じになりそう
→ただ普通の DRAM は思ったよりも遅い。 CPU がたったの 7 [MHz] でも
ランダムアクセスだと CPU にウェイトかける必要あり
DRAM が使えそうなのは ARCADE CARD の 2MB バッファ RAM くらい
メモリは 72-pin の SIMM モジュールが安いのでこれを使う
SIMM モジュールは某所からパクってきたので何 MB かわからない
→多分 32bitx4M が２枚で 32MB だと思う
XC95108PC84 x 2 を使用し 72 ピンの SIMM (EDO-DRAM)を 48MHz で制御する
SIMM を２枚制御できるかどうかは不明。64-bit にしなければできそう？？
ほぼ全てが初めての試み。PC ←→ 自作ハードの通信に USB を使うのも、
DRAM を使うのも 48MHz 動作も初めて
PIC16F873 と USBN9604 で USB 通信を行なう
PIC で USBN9604 を制御するソフトは後閑氏のページから戴いてきたものを
"NON-MULTIPLEXED MODE" パラレルインタフェイスに変更して使用
PIC16F873 は 16MHz (=48/3MHz) 動作（24MHz (=48/2MHz) を試したら動いたので余裕っぽい）
USB は full speed 動作。
取り込んだデータは XC95108PC84 → USBN9604 に DMA 転送する予定なので
データ転送速度は PIC16F873 の動作速度とはほとんど関係なくなる（はず）
基本的な制御部分で PIC16F873 のプログラムエリア半分弱（2kB）を使用
→まだあと半分も使える
当初 PIC16F873 の制御ソフトを SDCC で作成しようと試みたが現行版 (2.50 #1020 May 8 2005) では
配列とポインタの処理がまだうまく行なえないことを確認し断念
→結局 ASM で作成した

とりあえず後閑氏のページに公開されているプログラム(usbdvc1)を以下のように変更して使用しています。

変更箇所（覚えている限り）

p=16F876 → p=16F873
__CONFIG _HS_OSC & _WDT_OFF & _PWRTE_ON & _CP_OFF & _WRT_ENABLE_OFF & _LVP_OFF (太字部分追加)
INCLUDE "P16F876.INC" → INCLUDE "P16F873.INC"
LCD 制御部分を削除

; usbsym.h の最初の２行をコメントアウト
;#DEFINE	USBINT	PORTB,0		;RB0
;#DEFINE	USBCS	PORTB,1		;RB1

; USBN9604 ←→ PIC16F873 接続
#DEFINE	USBINT	PORTB,0		;RB0
#DEFINE	USBA0	PORTA,0		;A0
#DEFINE	USBCS	PORTA,1		;/CS
#DEFINE	USBRD	PORTA,2		;/RD
#DEFINE	USBWR	PORTA,3		;/WR
#DEFINE USBDATA	PORTC		;DATA

; マクロ追加 (usbmac.h)
USBDATA_IN	MACRO
	BANK1
	movlw	0ffh
	movwf	TRISC
	BANK0
	ENDM

USBDATA_OUT	MACRO
	BANK1
	movlw	0
	movwf	TRISC
	BANK0
	ENDM

init_PIC
	BANK1
	movlf	0x6,ADCON1		;RA0-5, RE0-2 = Digital
	movlf	0x00,TRISA		;RA0-5 = OUT
	movlf	0x01,TRISB		;RB0=INT
	movlf	0xff,TRISC		;RC0-7 = IN
	BANK0

	BSF	USBCS			;USBN9602 CS = 1 USBN9602 OFF
	BCF	USBA0			; A0 = L
	BSF	USBRD			; /RD = H
	BSF	USBWR			; /WR = H

	CLRF	USTATUS 		;USB用変数の初期化
	CLRF	STALLD			;USB用変数の初期化
	CLRF	DATAPID 		;USB用変数の初期化

	RETURN

; ディスクリプタ送信 (SENDDESC) 部分
NXT630
	USBDATA_OUT
	MOVLW	TXD0
	IORLW	0xC0
	BSF	USBA0
	MOVWF	USBDATA
	BCF	USBCS
	BCF	USBWR
	BSF	USBWR
	BCF	USBA0

LP67
	MOVF	DESC_INDEX,W
	CALL	DESC
	MOVWF	USBDATA
	BCF	USBWR
	BSF	USBWR
	INCF	DESC_INDEX,F
	DECFSZ	G_CNT,F
	GOTO	LP67
	BSF	USBCS
	USBDATA_IN

; PIC16F873 ← USBN9604 読み出し
RD_USB
	; write address
	MOVWF	UADR
	USBDATA_OUT
	MOVFF	UADR, USBDATA
	BSF	USBA0
	BCF	USBCS
	BCF	USBWR
	BSF	USBWR
	BCF	USBA0

	; read data from the address
	USBDATA_IN
	BCF	USBRD
	MOVF	USBDATA, W
	BSF	USBRD
	BSF	USBCS
	RETURN

; PIC16F873 ← USBN9604 連続読み出し
RD_USB_BURST
	; write address
	USBDATA_OUT
	BSF	USBA0
	MOVFF	UADR, USBDATA
	BCF	USBCS
	BCF	USBWR
	BSF	USBWR
	BCF	USBA0

	; read data from the address
	USBDATA_IN
LP20
	BCF	USBRD
	MOVFF	USBDATA, INDF
	BSF	USBRD
	INCF	FSR,F
	DECFSZ	G_CNT,F
	GOTO	LP20
	BSF	USBCS
	RETURN

; PIC16F873 → USBN9604 書き込み
WR_USB
	; write address
	USBDATA_OUT
	BSF	USBA0
	MOVF	UADR, W
	IORLW	0x80
	MOVWF	USBDATA
	BCF	USBCS
	BCF	USBWR
	BSF	USBWR
	BCF	USBA0

	; write data to the address
	MOVFF	UDAT, USBDATA
	BCF	USBWR
	BSF	USBWR
	BSF	USBCS
	USBDATA_IN
	RETURN

; PIC16F873 → USBN9604 連続書き込み
WR_USB_BURST
	; write address
	USBDATA_OUT
	BSF	USBA0
	MOVF	UADR, W
	IORLW	0xC0
	MOVWF	USBDATA
	BCF	USBCS
	BCF	USBWR
	BSF	USBWR
	BCF	USBA0

	; write data to the address
LP17
	MOVFF	INDF, USBDATA
	BCF	USBWR
	BSF	USBWR
	INCF	FSR, F
	DECFSZ	G_CNT,F
	GOTO	LP17
	BSF	USBCS
	USBDATA_IN
	RETURN

PIC16F873  ←→  USBN9604 接続 (あとで回路図描きます)
------------------------------------------------------
 RC0-RC7   ←→ D0-D7
 RA0        →  A0
 RA1        →  /CS
 RA2        →  /RD
 RA3        →  /WR
 RB0        ←  INTR
 CLKIN      ←  CLKOUT
/MCLR = H       /RESET= H
VDD = +5V       MODE0 = MODE1 = DRQ = AGND = GND
VSS = GND       V3.3 → 1.5kOhm → D+
その他はNC      VCC = +5V
------------------------------------------------------

目次へ戻る　 PCE 互換機の開発メモ　 トップページ

[Aug.20 2006] Logic Analyzer(?) の回路図 (V0.8)

回路図書いてみました。汚いですが．．．

↑回路図 V0.8（クリックで拡大）

所見

結局 SIMM モジュールは１個だけ使うことにした
SIMM モジュールのピーク消費電流はモジュール１個あたり 1[A] くらいになる
この規模になってくると、うまく動く気がしない → とりあえず V0.8 くらいにしとくか
CPLD を１個しか使っていないが、これも怪しい
CPLD ２個で処理を分散させる必要があるかもしれない
いずれにせよ CPLD をどう使うかがキーになる
USBN9604, PIC16F873 まわりは動作確認済み
CLK16M は CPLD で CLK48M を 3 分周して生成する
CLK48M は PIC から USBN9604 の CLKDIV をゼロに設定して CLKOUT ピンから取り出す
USBN D0-D7, USBN DRQ, USBN /DACK は CPLD --> USBN9604 DMA 転送用に使用する
DMA を使用しない場合は DRQ を 'H' に固定し、USBN D0-D7 と USBN /DACK は未接続とする

CPLD の記述は現在こんな感じです。シミュレーション上では EDO Page Mode Early Write Cycle と CBR Refresh Cycle はできてそうです。 CPLD --> DMA 転送機能の記述はまだしてません。この辺を実装したら１つの CPLD に収まらなくなるかもしれません。

/OE の動作を記述してありますが、後で SIMM モジュールの回路を見たら SIMM は /OE が全部 'L' 固定でした。やられた。

目次へ戻る　 PCE 互換機の開発メモ　 トップページ

[Aug.27 2006] Logic Analyzer(?) 配線完了 (V0.9)

配線しました。

↑右側の CPLD は飾り(笑)

↑74VHC244 (SOP20-P-300-1.27)をハンダ面にマウントする技術を会得

所見

CPLD は１個でなんとかなるかどうかというところ
トリガ機能を付ける余裕がほとんどない．．．
とりあえず写真右側の CPLD は未接続 → 飾り
DMA を実装すると２個いりそう．．． → 実装はまたの機会に．．．(苦)
DMA 使わないと転送速度が激遅な予感．．．
74VHC244 (SOP) の配線に神経を使った (疲れた．．．)
今さらながら FPGA を使えばかなり楽だった気が．．．
通電してみたらリフレッシュは動いてるっぽい
24Msps でデータを取り込めるはず
SIMM は 4M x 32-bit だから約 4/24 ~= 1/6 秒でメモリを使い切る
PIC も動いている

回路図は正常動作が確認できたら更新します。

とりあえず PIC と USBN9604 と CPLD の少なくとも一部は動いているので、 PC と通信させてデバッグすることにします。

なんか Logic Analyzer として実用になるのかどうか怪しくなってきましたが、今回の成果として USB が使えるようになることと、 DRAM コントローラ（ステートマシン）を書けるようになることができればまぁ OK とします。

目次へ戻る　 PCE 互換機の開発メモ　 トップページ

[Sep.03 2006]

とりあえず動きました。アドレスの動作がまだおかしいですが。 SIMM → PC 転送を全て PIC にやらせたら、転送速度が激遅で使い物になりませんでした(16KB の転送に数秒かかる)。やはり DMA を実装するしかなさそうです。あぁ、CPLD １個に入りきるかなー

[Sep.10 2006]

XC9536PC44 に 32-bit カウンタをプログラミングしてデバッグ中
XC9536PC44 は CLK, RESET に信号線を 2 本使うと、残る I/O ピンは 32 本！
→ 今回のデバッグにうってつけ
アドレスの動作がおかしいのを修正(いつのまにか直った)
いろいろゴニョゴニョいじっていたら PIC16F873 16MHz 動作で転送速度 270kB/s くらい出るようになった
→ 16MB の転送だと約 1 分かかる
PIC の動作速度でかなり転送速度も変わるので、やはり PIC が転送速度のネックになっているようだ
→ USBN9604 から 16MHz をもらわずに 20MHz のクリスタルで動かせば 300kB/s は出そう
PIC16F873 → USBN9604 → PC の転送はエラーなしでできている
DRAM → CPLD か CPLD → PIC16F873 がおかしい
やはり CPLD か．．．
DMA はやっぱり面倒なので実装しないことにした(1 分くらいガマンするか)

今回のサブプロジェクトは、なかなか勉強になります。

[Sep.16 2006]

ついに期待通りの動作をするようになりました。

所見

ついに完成
いろいろデバッグした
EDO-DRAM のコントローラなどというマイナーなものを作っている人はあまりいないらしく、
参考になるコードが見つからず苦労した
もうこのまま永遠に動くことはないのでは、とちょっと思いはじめていた
CPLD → PIC16F873 動作時の CPLD 側のバグが２つもあった
↑の 32-bit カウンタの動作読み出しテストはインクリメント／デクリメントともにクリア
早速 PC Engine につないでテストプログラムの動作を解析してみた→テストプログラムと結果
（注意：テキストファイルが巨大なため、メモ帳などで開くとアプリケーションが固まります。なるべくきちんとしたテキストエディタで開いてください。ワードパッドは辛うじてＯＫ。）
アドレスが変化するところで変な値になっているところがあるが、ちゃんと読めている模様
感動

↑またいろいろかき集めてテスト

回路図とかはそのうちまとめて掲載します。

目次へ戻る　 PCE 互換機の開発メモ　 トップページ

[Sep.17 2006] Logic Analyzer(?) 完成 (V1.0)

とりあえずこれで完成とします。

↑回路図 V1.0（クリックで拡大）

CPLD ソース (HTML) → DramCtrl10.html

CPLD ソース(DramCtrl.v) + pin constraint file (DramCtrl.ucf) → DramCtrl.tar.gz

PC 側プログラム (USB.c) → USB.tar.gz

PC 側プログラム (USB.c) は、柏野氏の Universal USB Driver Ver 2.0β を利用させていただきました。

所見

DRAM のデータシートを見ていたら、
「電源 ON 後 200[us] 待機してからリフレッシュサイクルを８回以上実行する必要あり」
ということが書いてあった
↑CPLD に一応実装してあるけど、きちんと電源 ON 後に 200[us] 待機しているかどうかは未確認
(レジスタに初期値を与えているが、これが電源 ON 時に初期化されるかどうかはデバイス依存っぽい)
リセット後はちゃんと待機しているはず（とりあえずいつかどこかで待機すればいいという勝手な解釈）
↑の記述ではタイミングがやや厳しめのため(?)、SIMM モジュールによってはうまく動作しない
→メモリ IC の数が多い SIMM モジュールでは電源の容量不足で動作不良を起こす可能性あり
→ 5[V] 2[A] くらい欲しい
i_Data[31:0] の入力を r_Data0[7:0] と r_Data1[7:0] に multiplex して、さらに出力時にも multiplex している
32-bit → 8-bitx4 の multiplexer をそのまま実装したら回路の動作速度が半減したため
(たぶんデータ信号線の一部がＦＢを２段通過している → なひたふ氏の FreeDIMM (仮称) を参照)
タイミングが厳しいのは T_RAS, T_RP。あと注意が必要なのは T_RCD/T_RAD
- T_RAS は /RAS が L になっている期間 (60[ns] < T_RAS < 10000[ns])
- T_RP は /RAS が H になってから次に L になるまでの期間 (> 40[ns])
- T_RCD は /RAS が L になってから /CAS が L になるまでの期間 (14[ns] < T_RCD < 45[ns])
- T_RAD は /RAS が L になってから Column Address 出力されるまでの期間 (12[ns] < T_RAD < 30[ns])
今回は CLK=48[MHz] なので 1T=20.83333[ns], 2T=41.66666[ns], 3T=62.49999[ns]
T_RAS = 3T, T_RP = 2T としているため、このへんが厳しいのではないかと思う
- データシートではクロックの transition にかかる時間を 2[ns] としてある
- クロックのたち下がりとたち上がりにそれぞれ 2[ns] かかることを加味すると、今回の設計では
  T_RAS = 58.49999[ns], T_RP = 37.66666[ns] → DRAM の仕様を満たさない
- CLK=48[MHz] だと T_RAS = 4T, T_RP = 3T としないと動かない SIMM モジュールが多いかも
T_RCD/T_RAD は MAX 値が小さいため、48[MHz] 動作だと T_RCD は最大 2T、T_RADは 1T 以内に収める必要がある

PIC のプログラム（変更部分）です。参考までに。

init_PIC
        BANK1
        movlf  0x6, ADCON1              ;RA0-5, RE0-2 = Digital
        movlf  0x00, TRISA              ;RA0-5 = OUT
        movlf  0x03, TRISB              ;RB0=INT, RB1=/BUSY
        movlf  0xff, TRISC              ;RC0-7 = IN
        BANK0

        BSF    USBCS                    ;USBN9602 CS = 1 USBN9602 OFF
        BCF    USBA0                    ; A0 = L
        BSF    USBRD                    ; /RD = H
        BSF    USBWR                    ; /WR = H

        BSF    CPLD_ACQUIRE             ; /ACQUIRE=H
        BSF    CPLD_TRANSFER            ; /TRANSFER=H

        BCF    CPLD_RESET               ;RESET CPLD
        BSF    CPLD_RESET               ;RESET CPLD

        CALL   T200us
        CALL   T200us

        CLRF   USTATUS                  ;USB用変数の初期化
        CLRF   STALLD                   ;USB用変数の初期化
        CLRF   DATAPID                  ;USB用変数の初期化

        RETURN


;-------------------------------------------------------------
DO_TX3_TRANSFER
        ; pipe 4
        ; write address
        USBDATA_OUT

        BSF    USBA0
        MOVLW  TXD3
        MOVWF  USBDATA
        BCF    USBCS                ; activate USBN9604
        BCF    USBWR
        BSF    USBWR
        BCF    USBA0

        movlf  64, G_CNT

        USBDATA_IN

        ; write data to the address
TXBLOOP4
        BCF    CPLD_TRANSFER
        BCF    USBWR
        BSF    USBWR
        BSF    CPLD_TRANSFER
        DECFSZ G_CNT, F
        GOTO   TXBLOOP4
        BSF    USBCS

        RETURN


;-------------------------------------------------------------
DO_TX3                              ;PIPE4 EP5
        CALL   DO_TX3_TRANSFER
        RETURN


;-------------------------------------------------------------
DO_RX1                              ;PIPE1 EP2
        movlf  R1_DAT0,FSR          ;GET COMMAND
        MOVF   INDF,W

        XORLW  'A'                  ; A: Acquire
        BTFSC  STATUS,Z
        GOTO   RX1_ACQUIRE

        MOVF   INDF,W
        XORLW  'T'                  ; T: Transfer
        BTFSC  STATUS,Z
        GOTO   RX1_TRANSFER

        GOTO   RX1_END

RX1_ACQUIRE
        ; reset cpld
        BCF    CPLD_RESET
        BSF    CPLD_RESET

        CALL   T200us
        CALL   T200us

        ; acquire
        BCF    CPLD_ACQUIRE
WAIT_ACQ:
        BTFSS  CPLD_BUSY
        GOTO   WAIT_ACQ
        BSF    CPLD_ACQUIRE

        GOTO   RX1_END


RX1_TRANSFER
        CALL   DO_TX3_TRANSFER
        CALL   TX3_PID_NO_TGL          ;SEND 


;-------------------------------------------------------------
RX1_END
        RETURN

RX_1
        MOVLW  RXS1                    ;RXｽﾃｰﾀｽを調べる
        CALL   RD_USB
        MOVWF  RXSTAT

        BTFSS  RXSTAT, BSETUP_R
        GOTO   NXT610                  ;setupでないならNXT610へ
        GOTO   EX_RX1                  ;ﾘﾀｰﾝ

NXT610  BTFSS  RXSTAT, BRX_ERR
        GOTO   NXT611                  ;errorでないならNXT611へ
        GOTO   EX_RX1                  ;ﾘﾀｰﾝ

NXT611
        movlf  R1_DAT0, FSR            ;FIFO1からR1_DATへ8Bﾃﾞｰﾀ受信
        movlf  8, G_CNT
        movlf  RXD1, UADR
        CALL   RD_USB_BURST

        CALL   FLUSHRX1                ;RX1をｵﾌ

;************* EP2の内部実行処理 ***
        CALL   DO_RX1                  ;処理ﾙｰﾁﾝへ

EX_RX1
        movlf  RXC1,UADR               ;RX1を使用可
        movlf  RX_EN,UDAT
        CALL   WR_USB
        RETURN

;-------------------------------------------------------------
TX_3
        MOVLW  TXS3                    ;TXS3のSTATUSを読む
        CALL   RD_USB
        MOVWF  TXSTAT

        BTFSS  TXSTAT,BACK_STAT        ;データ送信が無事終了したか
        GOTO   TX3_FAIL                ;問題があればTX3_FAILへ
        BTFSS  TXSTAT, BTX_DONE
        GOTO   TX3_FAIL

;*****  送信データ処理
        CALL   DO_TX3                  ;USER PROCESS

        BNOT   TGL3PID                 ;DATA種を反転
        CALL   TX3_PID_NO_TGL          ;TX3 送信可
        GOTO   EX_TX3

TX3_FAIL                               ;エラー処理（再送）
        BSF    PORTB,5
        CALL   DO_TX3_TRANSFER

EX_TX3
        RETURN

Logic Analyzer (?) －完－

目次へ戻る　 PCE 互換機の開発メモ　 トップページ

[Sep.23 2006] Logic Analyzer(?) Ver. 1.1

手持ちの全ての SIMM モジュールで動作させようと、 T_RAS = 4T, T_RP = 3T に変更してみましたが、相変わらず変な値が帰ってくる箇所がかなりあります。
なんでだー

動く SIMM モジュールは沖電気の M5117405A-60SJ が 9 個実装されているやつで（１個は多分パリティ用）、動かない SIMM モジュールは富士通の 8117405B-60 が 8 個、814105C-60 （多分パリティ用）が 4 個実装されています。パリティは使っていないのでとりあえず置いておいて、型番の下 6 ケタ (117405) が同じなのでほぼ互換性のあるチップだと思うんですが、8117405B-60 の方は今のところ使えないです。

一応現行版を置いておきます。タイミングに余裕を持たせたのと、あとメモリのアクセス部分を少し単純化しました。

CPLD ソース(DramCtrl.v) + pin constraint file (DramCtrl.ucf) Rev. 1.1 → DramCtrl11.tar.gz

目次へ戻る　 PCE 互換機の開発メモ　 トップページ

[Ock.01 2006] Logic Analyzer(?) まとめ

まとめというか、思ったことを書きます。

72-pin SIMM を XC95108 １個で制御することは可能
リソース使用率

Macrocells Used Pterms Used Registers Used Pins Used Function Block Inputs Used

95/108 (88%) 304/540 (57%) 74/108 (69%) 61/69 (89%) 197/216 (92%)
SIMM モジュールによっては動かない
- 原因不明
- まだバグが残っている可能性大
- SIMM モジュールは寿命が短いものがあるらしい(３～４年? 未確認情報)
- SIMM モジュールが死んでいる可能性があるが、未確認
- 動かない方の SIMM を PC に載せてチェックしたいけど SIMM を載せれる PC がない
PC 用 SIMM モジュールの動作電圧は 5[V]
- やたら電流を消費する
- SIMM モジュール + CPLD で 2[A] 以上欲しい
- 3.3[V] ロジックを読むのは辛い
- 3.3[V] 動作の DRAM は SD-RAM になるか
USBN9604 制御用の PIC プログラム
- 後閑氏のページから戴いてきたものを改造・流用した
- 転載の制限は特になさそう → とりあえずここから入手可能
- いくつかバグが残っているが、さしあたり問題ないので修正していない
- 既知のバグ： 'T' (転送コマンド)を受け取って、16MB 転送した後、もう一度 'T' を受け取ったときに「データ種」のトグルをうまく行なわないので転送を続行できない → 'A' (取り込みコマンド) と 'T' を繰り返す場合にこのバグを修正する必要あり
- あとで後閑氏のページをよく見たら、私が流用したもの(usbmain.lzh)の改良版が置いてあった(usbmaina.lzh)
- これから始める人は改良版から usbmaina.lzh からスタートするのがいいかも
- SDCC でそこそこ PIC のコードが書けるようになったら PIC-USBN9604 処理を C 言語で書きたい
転送速度
- 16MB の転送に１分くらい → 280kB/s 弱
- やはり１分は少し長い
- CPLD に DMA を実装するのは空きが少なすぎるか
- DMA とまではいかなくても、転送時の 64 バイトの書き込みを PIC ではなく CPLD に任せれば飛躍的に高速化できそう
保護回路
- 保護回路をつけていない
- ダンパー抵抗もつけていない
- この辺が少し気持ち悪い

Macrocells Used	Pterms Used	Registers Used	Pins Used	Function Block Inputs Used
95/108 (88%)	304/540 (57%)	74/108 (69%)	61/69 (89%)	197/216 (92%)

こんなところです。また何か思いついたら追加します。

Logic Analyzer(?) の製作

[Oct.01 2006] まえがき

[Jul.23 2006] Logic Analyzer(?) の製作

↑やっと USB でハードウェアの認識ができた

製作動機

所見

変更箇所（覚えている限り）

[Aug.20 2006] Logic Analyzer(?) の回路図 (V0.8)

↑回路図 V0.8（クリックで拡大）

所見

[Aug.27 2006] Logic Analyzer(?) 配線完了 (V0.9)

↑右側の CPLD は飾り(笑)

↑74VHC244 (SOP20-P-300-1.27)をハンダ面にマウントする技術を会得

所見

[Sep.03 2006]

[Sep.10 2006]

[Sep.16 2006]

所見

↑またいろいろかき集めてテスト

[Sep.17 2006] Logic Analyzer(?) 完成 (V1.0)

↑回路図 V1.0（クリックで拡大）

CPLD ソース (HTML) → DramCtrl10.html

CPLD ソース(DramCtrl.v) + pin constraint file (DramCtrl.ucf) → DramCtrl.tar.gz

PC 側プログラム (USB.c) → USB.tar.gz

所見

Logic Analyzer (?) －完－

[Sep.23 2006] Logic Analyzer(?) Ver. 1.1

CPLD ソース(DramCtrl.v) + pin constraint file (DramCtrl.ucf) Rev. 1.1 → DramCtrl11.tar.gz

[Ock.01 2006] Logic Analyzer(?) まとめ

(C) Ki 2006